Step by Step Guide: Mencari kata paling belakang

Kita akan mencari kata paling belakang dari suatu kelompok cells, dimana panjang kalimat tidak beraturan sehingga kita harus menggunakan :

• Mid, mengambil text sesuai posisi dan panjang tertentu
• Substitute, menggantikan text denga text lainnya
• Len, menghitung jumlah/panjang teks
• Trim, membuang kelebihan spasi

Disini rumusnya sangat kompleks dan sangat panjang sehingga kita ada kemungkinan salah ketik, oleh karena itu kita akan memakai cara step by step formula

Rumus lengkapnya

=MID(TRIM(A3),FIND("^",SUBSTITUTE(TRIM(A3)," ","^",LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))))+1,99)

Caranya akan kita terangkan dengan cara idiot dulu

1. Kita akan buang semua spasi yang berlebih ditext diatas
2. lalu Kita akan hitung dulu jumlah spasi yang tersisa
3. Kita ganti spasi terakhir dengan tanda ^
4. Kita cari posisi spasi yang terakhir (yg sudah berubah menjadi ^)
5. Kita ambil mulai dari posisi tsb+1 sampai 99 karakter (demi safe-nya)
6. Kata terakhir ketemu!

Lihat gambar dibawah ini

Langkah 1

1. Kita buang semua kelebihan spasi cell A3
2. yang dimaksud kelebihan spasi adalah semua spasi diawal , semua spasi diakhir, dan spasi yang lebih dari satu diantara 2 kata
3. Kita buang dng fungsi trim, kita ketik di B3
5. =TRIM(A3)

1. Cari jumlah Spasi dengan rumus di cell C3
2. rumus ini akan menghitung jumlah spasiyaitu dengan membandingkan text (B3) dengan text yang semua spasinya telah dibuang habis (kita substitute spasi dengan ""/blank),  selisihnya itulah jumlah spasi
4. =LEN(B3)-LEN(SUBSTITUTE(B3," ",""))

1. lalu kita akan ganti spasi yang terakhir dengan karakter ^ (karakter apa aja boleh, yg penting kita yakin kalo karakter tersebut tidak ada pada nama orang tsb, aneh juga kalo emang ternyata ada, mungkin nama orang rusia,…. serta jangan karakter wildcard seperti *,?,~)
2. Kita pake formula SUBSTITUTE, kita ganti spasi terakhir (atau sama dengan jumlah spasi)
3. Rumusnya di D3
5. =SUBSTITUTE(B3," ","^",C3)
7. Kita pakai hasil di C3 yang merupakan jumlah spasi/atau petunjuk spasi yang terakhir
8. Hasilnya adalah
9. Daniel^Erwin

1. Kita cari letak dari karakter ^ dengan fungsi FIND
2. Rumusnya di E3
4. =FIND("^",D3)
6. akan menemukan di posisi 7

1. Kita ambil kata terakhir dengan fungsi Mid
2. Kata yang diambil adalah di cell B3
3. Dng posisi awal adalah cell E3yaitu 7
4. Kita perlu +1 karena posisi 7 adalah karakter ^
5. dengan jumlah huruf yg mo diambil 99 (biar safe)
6. Rumusnya di cells F3
7. 
   
8. =MID(B3,E3+1,99)
9. 
   
10. Ketemu kata Erwin

1. Selesai….?
2. belumlah……kita coba akan menggabungkan rumus2 diatas menjadi satu tapi kita balik urutannya
3. Kita ketik di cells G3
4. atau tepatnya Edit - Copy-Paste dari cell F3
5. =MID(B3,E3+1,99)
6. 
   
7. Kita ganti kata E3 dengan rumus di E3
9. =MID(B3,FIND("^",D3)+1,99)
11. Kita ganti kata D3 dengan rumus di D3
12. 
    
13. =MID(B3,FIND("^",SUBSTITUTE(B3," ","^",C3))+1,99)
15. Kita ganti kata C3 dengan rumus di C3
16. 
    
17. =MID(B3,FIND("^",SUBSTITUTE(B3," ","^",LEN(B3)-LEN(SUBSTITUTE(B3," ",""))))+1,99)
18. Terakhir kita ganti B3 dengan Rumus di B3
19. 
    
20. =MID(TRIM(A3),FIND("^",SUBSTITUTE(TRIM(A3)," ","^",LEN(TRIM(A3))-LEN(SUBSTITUTE(TRIM(A3)," ",""))))+1,99)
22. Begitulah cara membuat formula yang rumit
23. Hasilnya sama dengan kalau kita membuat perbagian – lihat gambar diatas
24. Ini baru rampung

Sumber: http://www.microsoft-studios.com/excel/penerapan-excel-formula/text-functions/mencari-kata-paling-belakang/